A template for curvature calculations, using the (Subscript[AdS, 5]) BH in the u coordinate as an example.

input the metric :

ff=1-(u^2);

g:=(({{((-ff l^2)/(u rH^2)), 0, 0, 0, 0}, {0, ((l^2)/(u rH^2)), 0, 0, 0}, {0, 0, ((l^2)/(u rH^2)), 0, 0}, {0, 0, 0, ((l^2)/(u rH^2)), 0}, {0, 0, 0, 0, ((l^2)/(4(u^2)ff))}}))

compute all the curvatures

indep={t,x1,x2,x3,u};dim = Length[indep]; n = dim;gi = FullSimplify[Inverse[g]];
CrSym[gg_, gi_, i_, j_, k_] := Sum[gi[[i,l]]*(D[gg[[j, l]],indep[[k]]]+D[gg[[k,l]],indep[[j]]] - D[gg[[j, k]],indep[[l]]]), {l, 1, dim}] / 2 
riemann[cr_, i_, j_, k_, l_] :=( D[cr[[i,j,l]],indep[[k]]]) -( D[cr[[i,j,k]], indep[[l]]]) + (Sum[ cr[[i,m,k]]*cr[[m,j,l]] - cr[[i,m,l]]*cr[[m,j,k]], {m, 1, dim}])
ricci[rm_, i_, j_] := Sum[rm[[m,i,m,j]], {m, 1, dim}] ;
chrtab =  Table[CrSym[g, gi, i, j, k], {i, 1, dim}, {j, 1, dim}, {k, 1, dim}];

riemtab = Table[riemann[chrtab, i,j,k,l], {i, 1, dim}, {j, 1, dim}, {k, 1, dim}, {l, 1, dim}] ;

rictab = FullSimplify[ Table[ricci[riemtab,i,j], {i, 1, dim}, {j, 1, dim}]] ; 
rscal = FullSimplify[Sum[gi[[i,j]]*rictab[[j,i]],{i,1,dim},{j,1,dim}]] ;
ricup = Table[FullSimplify[Sum[gi[[i,ip]]*gi[[j,jp]]*rictab[[ip,jp]],{ip,1,dim},{jp,1,dim}]],{i,1,dim},{j,1,dim}];
einsteinallup = FullSimplify[ricup-gi*rscal/2];
einstein = rictab - (1/2)g rscal;
Print["ricci scalar = ", rscal]

check the einstein equation with cosmological constant

einstein - (6/(l^2)) g //Simplify//MatrixForm

whew.

if you really want to print out the curvatures :

CurvTable:=Table[If[UnsameQ[FullSimplify[einstein[[μ,κ]]],0],{(G^(ToString[μ -1] <> ToString[ κ-1])) ,FullSimplify[einstein[[μ,κ]]]}],{μ,1,n},{κ,1,n}]
TableForm[Partition[DeleteCases[Flatten[CurvTable],Null],2]]

CurvTable:=Table[If[UnsameQ[FullSimplify[rictab[[μ,κ]]],0],{(Subscript[R, ToString[μ -1] <> ToString[ κ-1]]) ,FullSimplify[rictab[[μ,κ]]]}],{μ,1,n},{κ,1,n}]
TableForm[Partition[DeleteCases[Flatten[CurvTable],Null],2]]

CurvTable:=Table[If[UnsameQ[FullSimplify[ricup[[μ,κ]]],0],{(Subscript[(R^(ToString[μ -1])), ToString[ κ-1]]) ,FullSimplify[ricup[[μ,κ]]]}],{μ,1,n},{κ,1,n}]
TableForm[Partition[DeleteCases[Flatten[CurvTable],Null],2]]

ConnTable:=Table[If[UnsameQ[FullSimplify[chrtab[[k,μ,ν]]],0],{(Subscript[(Γ^(ToString[k-1])), ToString[μ -1] <> ToString[ ν-1]]) ,FullSimplify[chrtab[[k,μ,ν]]]}],{k,1,n},{μ,1,n},{ν,1,n}]
TableForm[Partition[DeleteCases[Flatten[ConnTable],Null],2]]

CurvTable:=Table[If[UnsameQ[FullSimplify[riemtab[[α,μ,σ,λ]]],0],{(Subscript[(R^(ToString[α-1])), ToString[μ -1] <> ToString[ σ-1]<>ToString[ λ-1]]) ,FullSimplify[riemtab[[α,μ,σ,λ]]]}],{α,1,n},{μ,1,n},{σ,1,n},{λ,1,n}]
TableForm[Partition[DeleteCases[Flatten[CurvTable],Null],2]]